9c9d63b15a
This fixes PR27184, a failure to compile gdb due to cdefs.h being out of sync with glibc on ppc64le targets which are compiled with -mabi=ieeelongdouble and glibc 2.32. Likewise, update usage of _GL_ATTRIBUTE_FORMAT_PRINTF to _GL_ATTRIBUTE_FORMAT_PRINTF_STANDARD. Likewise, disable newly added rpl_free gnulib api in gdbserver support libraries. Likewise, undefine read/write macros before redefining them on mingw targets. Likewise, wrap C++ usage of free with GNULIB_NAMESPACE namespace as needed. Change-Id: I86517613c0d8ac8f5ea45bbc4ebe2b54a3aef29f
31 lines
1.3 KiB
Text
31 lines
1.3 KiB
Text
# clock_time.m4 serial 10
|
|
dnl Copyright (C) 2002-2006, 2009-2021 Free Software Foundation, Inc.
|
|
dnl This file is free software; the Free Software Foundation
|
|
dnl gives unlimited permission to copy and/or distribute it,
|
|
dnl with or without modifications, as long as this notice is preserved.
|
|
|
|
# Check for clock_gettime and clock_settime, and set LIB_CLOCK_GETTIME.
|
|
# For a program named, say foo, you should add a line like the following
|
|
# in the corresponding Makefile.am file:
|
|
# foo_LDADD = $(LDADD) $(LIB_CLOCK_GETTIME)
|
|
|
|
AC_DEFUN([gl_CLOCK_TIME],
|
|
[
|
|
dnl Persuade glibc and Solaris <time.h> to declare these functions.
|
|
AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
|
|
|
|
# Solaris 2.5.1 needs -lposix4 to get the clock_gettime function.
|
|
# Solaris 7 prefers the library name -lrt to the obsolescent name -lposix4.
|
|
|
|
# Save and restore LIBS so e.g., -lrt, isn't added to it. Otherwise, *all*
|
|
# programs in the package would end up linked with that potentially-shared
|
|
# library, inducing unnecessary run-time overhead.
|
|
LIB_CLOCK_GETTIME=
|
|
AC_SUBST([LIB_CLOCK_GETTIME])
|
|
gl_saved_libs=$LIBS
|
|
AC_SEARCH_LIBS([clock_gettime], [rt posix4],
|
|
[test "$ac_cv_search_clock_gettime" = "none required" ||
|
|
LIB_CLOCK_GETTIME=$ac_cv_search_clock_gettime])
|
|
AC_CHECK_FUNCS([clock_gettime clock_settime])
|
|
LIBS=$gl_saved_libs
|
|
])
|